关于众筹合约的有关问题,急在线等
发布于 17 天前 作者 LusWar 243 次浏览 来自 智能合约
pragma solidity ^0.4.23;

/**
 * @title 安全数学库
 * @dev 用于uint256的安全计算,合约内的代币操作均使用这个库的函数代替加减乘除,来避免上溢、下溢等问题
 */
library SafeMath {

	/**
	 * @dev 乘法
	 */
	function mul(uint256 a, uint256 b) internal pure returns (uint256 c) {
		if (a == 0) {
			return 0;
		}
		c = a * b;
		assert(c / a == b);
		return c;
	}

	/**
	 * @dev 除法
	 */
	function div(uint256 a, uint256 b) internal pure returns (uint256) {
		return a / b;
	}

	/**
	 * @dev 减法
	 */
	function sub(uint256 a, uint256 b) internal pure returns (uint256) {
		assert(b <= a);
		return a - b;
	}

	/**
	 * @dev 加法
	 */
	function add(uint256 a, uint256 b) internal pure returns (uint256 c) {
		c = a + b;
		assert(c >= a);
		return c;
	}
}

/**
 * @title 所有权合约
 * @dev 用于控制合约的所有权,可以转让所有权
 */
contract Ownable {
	address owner_; //合约所有者

	event OwnershipRenounced(address indexed previousOwner); //合约所有权放弃事件
	event OwnershipTransferred(address indexed previousOwner, address indexed newOwner); //合约所有权转让事件

	/**
	 * @dev 构造函数
	 */
	constructor() public {
		owner_ = msg.sender; //合约所有者为合约创建者
	}

	/**
     * @dev 合约所有者
     */
	function owner() public view returns (address) {
		return owner_;
	}

	/**
     * @dev onlyOwner函数修改器:判断合约使用者是不是合约拥有者,是合约拥有者才能执行
     */
	modifier onlyOwner() {
		require(msg.sender == owner_);
		_;
	}

	/**
	 * @dev 转让合约所有权:只有合约所有者能使用,转让合约所有权给newOwner
	 * @param  newOwner 新的合约所有者
	 */
	function transferOwnership(address newOwner) public onlyOwner {
		require(newOwner != address(0));
		emit OwnershipTransferred(owner_, newOwner);
		owner_ = newOwner;
	}
}

/**
 * @title ERC20代币合约
 * @dev 这是一个示例合约,众筹合约实际使用时,要用众筹合约的token代码替换这里的合约代码
 */
contract ERC20 is Ownable {

	using SafeMath for uint256; //uint256类型使用SafeMath库

	string name_; //代币名称
	string symbol_; //代币符号,类似货币符号
	uint8 decimals_; //小数点后位数
	uint256 totalSupply_; //发行总量

	mapping(address => uint256) balances; //地址余额映射
	mapping(address => mapping(address => uint256)) internal allowed; //授权额度映射

	event Transfer(address indexed from, address indexed to, uint256 value); //代币转账事件
	event Approval(address indexed owner, address indexed spender, uint256 value); //授权额度事件
	event OwnershipRenounced(address indexed previousOwner); //合约所有权放弃事件
	event OwnershipTransferred(address indexed previousOwner, address indexed newOwner); //合约所有权转让事件

	/**
	 * @dev 构造函数:web3代码生成后,需要自定义_name,_symbol,_decimals,_totalSupply
	 */
	constructor(string _name, string _symbol, uint8 _decimals, uint256 _totalSupply) public {
		name_ = _name;
		symbol_ = _symbol;
		decimals_ = _decimals;
		totalSupply_ = _totalSupply.mul(10 ** uint256(decimals_)); //发行总量按小数点后位数转换
		balances[owner_] = totalSupply_; //合约发布者持有初始所有代币
	}

	/**
	 * @dev 代币名称
	 */
	function name() public view returns (string) {
		return name_;
	}

	/**
	 * @dev 代币符号
	 */
	function symbol() public view returns (string) {
		return symbol_;
	}

	/**
	 * @dev 小数点后位数
	 */
	function decimals() public view returns (uint8) {
		return decimals_;
	}

	/**
	 * @dev 发行总量
	 */
	function totalSupply() public view returns (uint256) {
		return totalSupply_;
	}

	/**
	 * @dev onlyOwner函数修改器:判断合约使用者是不是合约拥有者,是合约拥有者才能执行
	 */
	modifier onlyOwner() {
		require(msg.sender == owner_);
		_;
	}

	/**
	 * @dev 代币转账:在合约未暂停时,由合约使用者msg.sender,向_to转入_value数量的代币
	 * @param  _to 转入地址 _value 代币数量
	 * @return  bool 是否转账成功
	 */
	function transfer(address _to, uint256 _value) public returns (bool) {
		require(_to != address(0));
		require(_value <= balances[msg.sender]);

		balances[msg.sender] = balances[msg.sender].sub(_value);
		balances[_to] = balances[_to].add(_value);
		emit Transfer(msg.sender, _to, _value);
		return true;
	}

	/**
	 * @dev 余额查询:查询_account地址的代币余额
	 * @param  _account 代币账户地址
	 * @return  uint256 代币余额
	 */
	function balanceOf(address _account) public view returns (uint256) {
		return balances[_account];
	}

	/**
	 * @dev 授权额度:在合约未暂停时,由合约使用者msg.sender,向_spender授权_value数量代币额度
	 * @param  _spender 被授权地址 _value 授权额度
	 * @return  bool 是否授权成功
	 */
	function approve(address _spender, uint256 _value) public returns (bool) {
		allowed[msg.sender][_spender] = _value;
		emit Approval(msg.sender, _spender, _value);
		return true;
	}

	/**
     * @dev 授额转账:在合约未暂停时,由合约使用者msg.sender,从_from向_to转入_value数量的代币,转账数量不能超过_from的授权额度和余额
     * @param  _from 授额地址 _to转入地址 _value 代币数量
     * @return  bool 是否转账成功
     */
	function transferFrom(address _from, address _to, uint256 _value) public returns (bool) {
		require(_to != address(0));
		require(_value <= balances[_from]);
		require(_value <= allowed[_from][msg.sender]);

		balances[_from] = balances[_from].sub(_value);
		balances[_to] = balances[_to].add(_value);
		allowed[_from][msg.sender] = allowed[_from][msg.sender].sub(_value);
		emit Transfer(_from, _to, _value);
		return true;
	}

	/**
	 * @dev 查询授额:查询由_owner向_spender授权的代币额度
	 * @param  _owner 授权地址 _spender 被授权地址
	 * @return  uint256 授权额度
	 */
	function allowance(address _owner, address _spender) public view returns (uint256) {
		return allowed[_owner][_spender];
	}

	/**
	 * @dev 增加授额:在合约未暂停时,由合约使用者msg.sender向_spender增加_addValue数量的代币额度
	 * @param  _spender 被授权地址 _addedValue 增加的授权额度
	 * @return  bool 是否增加授额成功
	 */
	function increaseApproval(address _spender, uint _addedValue) public returns (bool success) {
		allowed[msg.sender][_spender] = allowed[msg.sender][_spender].add(_addedValue);
		emit Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
		return true;
	}

	/**
	 * @dev 减少授额:在合约未暂停时,由合约使用者msg.sender向_spender减少_subtractedValue数量的代币额度
	 * @param  _spender 被授权地址 _subtractedValue 减少的授权额度
	 * @return  bool 是否减少授额成功
	 */
	function decreaseApproval(address _spender, uint _subtractedValue) public returns (bool success) {
		uint oldValue = allowed[msg.sender][_spender];
		if (_subtractedValue > oldValue) {
			allowed[msg.sender][_spender] = 0;
		} else {
			allowed[msg.sender][_spender] = oldValue.sub(_subtractedValue);
		}
		emit Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
		return true;
	}
}

/**
 * @title 基础众筹合约
 * @dev 基础的众筹合约包括购买token的功能
 */
contract BasicCrowdsale {
	using SafeMath for uint256;

	ERC20 public token; //众筹代币啊
	address public wallet; //众筹钱包
	uint256 public rate; //兑换比例 1wei能换多少token(未按精度转化的)
	uint256 public weiRaised; //筹集到的of数量,单位是wei

	/**
	 * @dev 代币购买事件
	 * @param purchaser 购买代币者 beneficiary 获得代币者 value of使用数量 amount 购买代币数量
	 */
	event TokenPurchase(address indexed purchaser, address indexed beneficiary, uint256 value, uint256 amount);

	/**
	 * @dev 构造函数
	 * @param _rate 兑换比例 _wallet 众筹钱包地址 _token 智能合约地址
	 */
	constructor(uint256 _rate, address _wallet, ERC20 _token) public {
		require(_rate > 0);
		require(_wallet != address(0));
		require(_token != address(0));

		rate = _rate;
		wallet = _wallet;
		token = _token;
	}

	// -----------------------------------------
	// 众筹外部接口
	// -----------------------------------------

	/**
	 * @dev 默认函数:可以直接给智能合约转账,相当于给msg.sender购买代币 ***不能重载***
	 */
	function () external payable {
		buyTokens(msg.sender);
	}

	/**
	 * @dev 代币购买:给_beneficiary购买代币 ***不能重载***
	 * @param _beneficiary 获得代币者
	 */
	function buyTokens(address _beneficiary) public payable {

		uint256 weiAmount = msg.value;
		_preValidatePurchase(_beneficiary, weiAmount);

		// 计算需要交付的代币数量
		uint256 tokens = _getTokenAmount(weiAmount);

		// 更新筹款数量
		weiRaised = weiRaised.add(weiAmount);

		_processPurchase(_beneficiary, tokens);
		emit TokenPurchase(
			msg.sender,
			_beneficiary,
			weiAmount,
			tokens
		);

		_updatePurchasingState(_beneficiary, weiAmount);

		_forwardFunds();
		_postValidatePurchase(_beneficiary, weiAmount);
	}

	// -----------------------------------------
	// 内部接口:可重载进行更复杂的实现
	// -----------------------------------------

	/**
	 * @dev 购买验证:验证正在进行的购买是否有效
	 * @param _beneficiary 获得代币者 _weiAmount 花费的of数量,单位是wei
	 */
	function _preValidatePurchase(address _beneficiary, uint256 _weiAmount) internal {
		require(_beneficiary != address(0));
		require(_weiAmount != 0);
	}

	/**
	 * @dev 购买验证:验证已经发生的购买
	 * @param _beneficiary 获得代币者 _weiAmount 花费的of数量,单位是wei
	 */
	function _postValidatePurchase(address _beneficiary, uint256 _weiAmount) internal {
		// optional override
	}

	/**
	 * @dev 交付代币:给_beneficiary交付_tokenAmount数量的代币
	 * @param _beneficiary 获得代币者 _tokenAmount 获得代币的数量
	 */
	function _deliverTokens(address _beneficiary, uint256 _tokenAmount) internal {
		token.transfer(_beneficiary, _tokenAmount);
	}

	/**
	 * @dev 处理购买:决定如何对购买代币进行处理
	 * @param _beneficiary 获得代币者 _tokenAmount 获得代币的数量
	 */
	function _processPurchase(address _beneficiary, uint256 _tokenAmount) internal {
		_deliverTokens(_beneficiary, _tokenAmount);
	}

	/**
	 * @dev 更新购买状态
	 * @param _beneficiary 获得代币者 _weiAmount 花费的of数量,单位是wei
	 */
	function _updatePurchasingState(address _beneficiary, uint256 _weiAmount) internal {
		// optional override
	}

	/**
	 * @dev 获得购买代币数量:按照兑换比例,计算需要交付的代币数量
	 * @param _weiAmount 花费的of数量,单位是wei
	 */
	function _getTokenAmount(uint256 _weiAmount) internal view returns (uint256){
		return _weiAmount.mul(rate);
	}

	/**
	 * @dev 转发筹款:用于将筹得的款项发送
	 */
	function _forwardFunds() internal {
		wallet.transfer(msg.value);
	}
}

这是我写的众筹合约,我先发了上面那个token合约,然后发了下面这个众筹合约, 我在众筹合约传入token合约的地址用于调用token的transfer,但我向众筹合约转账无法成功, 我的测试是token.transfer()在众筹合约里调用有问题,我做过几次测试,包括事先给众筹合约地址转入token,都没法使这个功能生效 现在我想问两个问题: 1、众筹合约调用上面的token合约时,token合约收到的msg.sender是众筹合约地址(我验证的是这样)? 2、我这样的调用存在什么问题,如何解决?

8 回复

人工置顶一哈,求解答

@LusWar 是不是因为众筹合约没有继承token合约呀?

@zhaoyao 众筹合约不需要继承token吧,如果继承token的话,相当于我把token和众筹变成一个合约了,这样我也不需要把token合约地址传入了,我都用一个合约就行了

@LusWar 你的众筹合约中调用token合约的话,token合约中msg.sender是你的众筹合约地址,要想使你的token.transfer调用成功,那你的众筹合约必须有你token合约的token。你创建token时,已经把所有token转给了创建的地址,你可转一部分给众筹合约,然后众筹合约应该能工作;(留接口可以收回众筹合约的token) ps:发代币合约不能急,token合约一旦有问题,损失一般都很大。

我找到了原因,原因是transfer有返回值,return true,我把返回参数去掉后,正常调用

@manxiaqu 你说的这个我知道,就是我要给众筹合约转token,因为msg.sender是众筹合约,我现在发现了的问题是,合约调用另一个合约的函数,如果函数有返回值,这个函数是无法被识别并使用的。

@LusWar 不知道你具体的调用情况是什么样的,但是合约调用另外一个合约,是可以使用另一个合约函数的返回值的。而且很多函数都会返回true和false,给其他函数调用者来判断执行是否成功,从而处理不同的情况。

@manxiaqu 能否私信一下qq或微信联系方式,有关这种调用方式,有些想跟您请教一下

回到顶部